Vegas pro 13 firewall block

[Driftersrift]

I cant find the Vegas pro in the list of programs via windows firewall block. Is it listed as something else? Everything is fine. But i have searched high and low, to no avail. any help would be amazing.

[LowOrbit]

Copy what's between the code tags below and save it to your desktop as FireWall_LazyBoy.bat  (NOT FireWall_LazyBoy.bat.txt):

Code:

   @ echo off
@setlocal enableextensions
@cd /d "%~dp0"
color 06
title LowOrbit FireWall LazyBoy
echo.
echo.           ========================================================
echo.           ==  Welcome to the LowOrbit / Devin FireWall LazyBoy  ==
echo.               == Your 1 Stop Application FireWall Blocker  ==
echo.           ========================================================
echo.
echo.
echo.           ========================================================
echo.                  =  A TRUE Collaborative Pirate Release  =
echo.                               ==  KOPIMI  ==
echo.           ========================================================
echo.
Echo Current location: %cd%
echo.
CHOICE /C YN /M "Do you want to search for executables in the current location?"
IF Errorlevel 2 goto END
IF Errorlevel 1 goto Yes




::--------------------CHECK and searching files-----------------
:Yes
set location=%cd%
cls
echo.
Echo. Searching for .exe files in %location%
echo.
set /a count=0
echo.___________________________________________
echo.Found:
echo.
FOR  %%i in (*.exe) do (echo. %%i & set /a count+=1)
echo.___________________________________________
echo.
title LowOrbit / Devin FireWall LazyBoy %count% Files found
echo. Number of files found with the .exe extention: %count%
echo.
echo.
set add2=

CHOICE /C YN /M "Do you want to add aditional information?"
IF Errorlevel 2 goto block
IF Errorlevel 1 goto ADD

::-----------------ADD additional info---------------
:ADD
Set /p add=Please type the additonal information for the name:
Set add2=%add%

::-----------------Add files to firewall--------------
:block
cls
title LowOrbit / Devin FireWall LazyBoy - Blocking Rules
set /a countt=0
echo.
echo.___________________________________________
echo. Inbound Rules
echo.___________________________________________
FOR /r %%B in (*.exe) do (set /a countt+=1 & echo.%countt%. %%~nxB blocking... & netsh advfirewall firewall add rule name="%add2%%%~nxB" dir=in action=block program="%%~dpfnxB")
echo.___________________________________________
echo. OutBound rules
set /a coun=0
echo.___________________________________________
FOR /r %%B in (*.exe) do (set /a coun+=1 & echo.%coun%. %%~nxB blocking... & netsh advfirewall firewall add rule name="%add2%%%~nxB" dir=out action=block program="%%~dpfnxB")
echo.___________________________________________
Echo. Added files to Windows FireWall
echo.
title LowOrbit / Devin FireWall LazyBoy locked
Pause

::------------------------END---------------------

:END
cls
ECHO.
Echo. Thanks for using LowOrbit / Devin FireWall LazyBoy
Echo.

CHOICE /C YN /T 10 /D n /M "Do you want to open Windows FireWall? (10 seconds)"
IF Errorlevel 2 goto EXIT
IF Errorlevel 1 goto OPEN

::------------------Open Firewall---------------
:OPEN
start "C:\Windows\System32" rundll32.exe shell32.dll,Control_RunDLL firewall.cpl
Goto EXIT


:EXIT

Copy/Paste it into the softwares installation directory, double click on it and follow the on-screen prompts and it will block all executables with inbound/outbound firewall rules in Windows Firewall.

Or,

Download it from my download link mirrors below:

https://www.mirrorcreator.com/files/1DV8....bat_links